home *** CD-ROM | disk | FTP | other *** search
/ Amiga Plus 1995 #5 & #6 / Amiga Plus CD - 1995 - No. 5 and 6.iso / tex / mf / inputs / cm / it_digits.mf < prev    next >
Text File  |  1993-11-28  |  12KB  |  263 lines
  1. % This is ITALD.MF in text format, as of Mar 31, 1986.
  2. % This file contains the ten digits in so-called italic style.
  3. % Character codes \0060 through \0071 are generated.
  4.  
  5. % The characters all have the same italic correction.
  6.  
  7. cmchar "Italic numeral 0";
  8. beginchar("0",9u#,fig_height#,0);
  9. italcorr fig_height#*slant-.5u#;
  10. adjust_fit(0,0);
  11. penpos1(vair,90); penpos3(vair,-90); penpos2(curve,180); penpos4(curve,0);
  12. if not monospace: interim superness:=sqrt(more_super*hein_super); fi
  13. x2r=hround(1.5u-.5curve); x4r=w-x2r; x1=x3=.5w;
  14. y1r=h+o; y3r=-o; y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
  15. penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  16.  & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle;  % bowl
  17. penlabels(1,2,3,4); endchar;
  18.  
  19. cmchar "Italic numeral 1";
  20. beginchar("1",9u#,fig_height#,0);
  21. italcorr fig_height#*slant-.5u#;
  22. adjust_fit(0,0); pickup tiny.nib;
  23. numeric light_stem; light_stem=hround .4[stem',cap_stem'];
  24. pos1(light_stem,0); pos2(light_stem,0);
  25. lft x1l=lft x2l=hround(.5(w+.5u)-.5cap_stem'); top y1=h+apex_o; bot y2=0;
  26. filldraw stroke z1e--z2e;  % stem
  27. dish_serif(2,1,a,1/3,min(2.25u,lft x2l-1.5u),
  28.   b,1/3,min(2.25u,w-1.25u-rt x2r)); % serif
  29. pickup crisp.nib; pos3(slab,-90); pos4(bar,-90);
  30. top y3l=h+apex_o; top y4l=.8h+apex_o;
  31. lft x4=max(1.25u,tiny.lft x1l-2.35u); tiny.rt x1r=lft x3+.25[tiny,hair];
  32. erase fill z3l{x4l-x3l,3(y4l-y3l)}...z4l{left}
  33.  --(x4l,h+apex_o+1)--(x3l,h+apex_o+1)--cycle; % erase excess at top
  34. filldraw stroke z3e{x4e-x3e,3(y4e-y3e)}..{left}z4e;  % point
  35. penlabels(1,2,3,4); endchar;
  36.  
  37. cmchar "Italic numeral 2";
  38. beginchar("2",9u#,fig_height#,0);
  39. italcorr fig_height#*slant-.5u#;
  40. adjust_fit(0,0); pickup fine.nib;
  41. pos1(vair,45); pos2(vair,0); pos3(vair,-90); pos4(hair,-180);
  42. pos5(vair,-270); pos6(curve,-360); pos7(hair,-405); pos8(hair,-360);
  43. x1=x2-.5u; rt x2r=hround(3.5u+.5vair);
  44. x3=.6[x2,x4]; lft x4r=hround(u-.5hair);
  45. x5=x7=.5w-.5u; rt x6r=hround(w-u); lft x8l=hround(1.5u-.5hair);
  46. y1=.5[x_height,h]; y2=1/3[y1,y3]; y4=x_height; bot y3r=vround .78y4;
  47. top y5r=h+o; y6=.5[y5,y7]; y7=.52y4; bot y8=-o;
  48. filldraw stroke if not hefty:z1e{2(x2-x1),y2-y1}...{down}z2e...{left}z3e...fi
  49.  z4e{up}...pulled_arc.e(5,6)
  50.  ...z7e{2(x7-x6),y7-y6}...{down}z8e; % main stroke
  51. pos9(vair,-90); pos10(vstem+curve-stem,-90); pos11(hair,0);
  52. x9=w-x10=2.5u; rt x11r=hround(w-.5u+.5hair);
  53. y9=.25[y10,y7]; bot y10r=-o; y11=.38x_height;
  54. filldraw stroke z8e{up}...z9e{right}..{right}z10e...{up}z11e;  % bar
  55. penlabels(1,2,3,4,5,6,7,8,9,10,11); endchar;
  56.  
  57. cmchar "Italic numeral 3";
  58. beginchar("3",9u#,fig_height#,0);
  59. italcorr fig_height#*slant-.5u#;
  60. adjust_fit(0,0); pickup fine.nib;
  61. pos1(vair,45); pos2(vair,0); pos3(vair,-90); pos4(hair,-180);
  62. pos5(vair,-270); pos6(stem,-360); pos7(bar,-450); pos8(bar,-450);
  63. x1=x2-.5u; rt x2r=hround(3.5u+.5vair); x3=.5[x2,x4]; lft x4r=hround u;
  64. x5=x7=.5w; rt x6r=hround(w-u); x8=x7-u;
  65. y1=.5[x_height,h]; y2=.5[y1,y3]; y7=y8=.52h; bot y3r=vround 1/4[y7,h];
  66. y4=1/3[y3,y5]; top y5r=h+o; y6=.5[y5,y7];
  67. filldraw stroke if not hefty: z1e{2(x2-x1),y2-y1}...{down}z2e...{left}z3e...fi
  68.  z4e{up}...pulled_arc.e(5,6) & pulled_arc.e(6,7)..z8e; % upper arc
  69. pos7'(vair,90); z7'l=z7r;
  70. pos9(curve,0); pos10(vair,-90); pos11(hair,-180); pos12(flare,-180);
  71. rt x9r=hround(w-u); x10=.5w-.5u; lft x11r=hround .75u;
  72. y9=.25h; bot y10r=-o; y11=1/3x_height; bulb(10,11,12);  % bulb
  73. filldraw stroke pulled_arc.e(7',9) & pulled_arc.e(9,10);  % lower arc
  74. penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
  75.  
  76. cmchar "Italic numeral 4";
  77. beginchar("4",9u#,fig_height#,desc_depth#);
  78. italcorr fig_height#*slant-.5u#;
  79. adjust_fit(0,0); pickup fine.nib;
  80. pos1(stem,0); pos6(stem,0); pos7(stem,0);
  81. pos2(bar,-45); pos3(bar,-90); pos4(bar,-90); pos5(bar,-45);
  82. rt x1r=hround(.5w+.5u+.5stem); lft x2l=hround .25u;
  83. x3=2.75u; x4=w-2u; rt x5r=hround(w-.25u);
  84. rt x6r=rt x7r=hround(2/3w+.5stem);
  85. y1+.5stem=h+o; bot y2r=0; bot y3r=vround(.08h-.5bar);
  86. bot y4r=vround-.5bar; bot y5r=vround(.03h-.5bar);
  87. y6+.5stem=bar_height; y7-.5stem=-d;
  88. filldraw circ_stroke z1e{down}...{3(x2-x1),y2-y1}z2e;  % diagonal
  89. filldraw stroke z2e{z1-z2}...z3e{right}..{right}z4e
  90.  ...{x5-x4,2(y5-y4)}z5e;  % bar
  91. filldraw z6l---z7l..z7r---z6r..cycle;  % stem
  92. penlabels(1,2,3,4,5,6,7); endchar;
  93.  
  94. cmchar "Italic numeral 5";
  95. beginchar("5",9u#,fig_height#,0);
  96. italcorr fig_height#*slant-.5u#;
  97. adjust_fit(0,0);
  98. numeric bot_thickness,light_hair;
  99. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  100. light_hair=hround(cap_hair if hefty: -\\2stem_corr fi);
  101. pickup tiny.nib; pos5(vair,180); pos6(vair,90);
  102. bot y5=vround(.53h-vair); top y6r=max(vround .61803h+o,top y6r+y5+eps-y6l);
  103. pos3(light_hair,0); pos4(light_hair,0);
  104. lft x3l=max(1.35u,2.1u-.5light_hair); x3=x4=x5; y4=y5;
  105. top y3=h if not hefty: +\\o fi;
  106. filldraw stroke z3e--z4e;  % thin stem
  107. penpos7(cap_stem-fine,0); penpos8(bot_thickness-fine,-90);
  108. fine.rt x7r=hround(w-.9u); x8=.5[u,x7]; x6=.5[x5,x7];
  109. erase fill z5--bot z5--(x6,bot y5)--z6{left}
  110.  ..tension .9 and 1..{x5-x6,3(y5-y6)}cycle; % erase excess in middle
  111. filldraw stroke z6e{left}..tension .9 and 1..{x5-x6,3(y5-y6)}z5e;  % link
  112. pickup fine.nib; pos6'(vair,90); z6'=z6;
  113. y7=.5[y6,y8]; bot y8r=-o;
  114. filldraw stroke pulled_arc.e(6',7) & pulled_arc.e(7,8);  % bowl
  115. if serifs: pos9(hair,-180); y9=.5y5; lft x9r=hround .9u;
  116.  pos10(flare+1/3(cap_stem-stem),-180); bulb(8,9,10);  % bulb
  117. else: pos9(3/7[bot_thickness,flare],angle(-7u,-h));
  118.  lft x9r=hround(tiny.lft x3l-.75u); bot y9r=vround .15h-o;
  119.  x9l:=good.x x9l; y9l:=good.y y9l;
  120.  filldraw stroke term.e(8,9,left,1,4); fi  % terminal
  121. if hefty: pickup crisp.nib; pos1(slab,90); pos2(hair,0);
  122.  top y1r=h; x1=x4; rt x2r=hround(w-1.5u); y2=y1l-eps;
  123.  arm(1,2,a,0,0);  % arm
  124. else: numeric flag_breadth; flag_breadth=7/8[vair,cap_curve];
  125.  pos1(flag_breadth,90); pos2(flag_breadth,60);
  126.  pos0(vair,90); top y1r=tiny.top y3; top y2r=vround .95h+o; y0r=y1r;
  127.  lft x1=tiny.lft x3l; x2r=.5[x1,x0]; rt x0=hround(w-1.6u);
  128.  erase fill top z1r--z1r...{right}z2r
  129.   --(x2r,top y1r)--cycle; % erase excess at top
  130.  filldraw stroke z1e...{right}z2e...z0e; fi  % flag
  131. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  132.  
  133. cmchar "Italic numeral 6";
  134. beginchar("6",9u#,fig_height#,0);
  135. italcorr fig_height#*slant-.5u#;
  136. adjust_fit(0,0);
  137. numeric top_thickness,bot_thickness,side_thickness,pull;
  138. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  139. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  140. side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
  141. pull=min(.25,1.5superpull);
  142. pickup fine.nib; pos2(top_thickness,-270);
  143. pos3(side_thickness,-180); pos4(bot_thickness,-90);
  144. pos5(side_thickness,0); pos6(vair,90);
  145. lft x3r=w-rt x5r=hround max(.75u,1.5u-.5side_thickness);
  146. x4=x6-.1u=x2-u=.5w;
  147. top y2r=h+o; y3=.5[y2,y4]; bot y4r=-o;
  148. y5=.5[y4,y6]; top y6=vround 5/8h+o;
  149. path p; p=pulled_super_arc.l(3,4)(pull);
  150. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  151. pos7(thin_join,180); z7l=point t of p;
  152. (x,y6r)=whatever[z7l,z6l]; x6r:=min(x,.5[x5r,x6]);
  153. filldraw stroke pulled_super_arc.e(2,3)(pull)
  154.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  155.  & {{less_tense; pulled_super_arc.e(4,5)(pull)
  156.  & pulled_super_arc.e(5,6)(pull)}}
  157.  & z6e{left}...{direction t of p}z7e;  % arc and bowl
  158. if serifs: pos1(hair,-360); pos0(flare,-360);
  159.  rt x0r=max(rt x2+eps,hround(w-1.2u));
  160.  y0=vround min(.9h-.5flare,.85h+.5flare)+o;
  161.  {{less_tense; bulb(2,1,0)}};  % arc and bulb
  162. else: pos1(vround .1[top_thickness,flare],90);
  163.  top y1r=vround .97h+o; rt x1=hround(x5-.5);
  164.  filldraw stroke term.e(2,1,right,.9,4); fi  % terminal
  165. penlabels(0,1,2,3,4,5,6,7); endchar;
  166.  
  167. cmchar "Italic numeral 7";
  168. beginchar("7",9u#,fig_height#,desc_depth#);
  169. italcorr fig_height#*slant-.5u#;
  170. adjust_fit(0,0); pickup fine.nib;
  171. numeric fat_curve; fat_curve=1.4[stem,curve];
  172. pos1(hair,0); pos2(hair,0); pos3(vstem+curve-stem,-90);
  173. pos4(vair,-90); pos5(hair,0); pos6(fat_curve,0);
  174. top y1=h+o; y2=x_height; y3l=y5=y1;
  175. bot y4r=vround(.5[y2,h]-.5vair); y6-.5fat_curve=-o;
  176. lft x2l=hround(.5u-.5hair); x3=.5w-.5u; x4=2/3w;
  177. rt x5r=hround(w-.75u+.5hair); rt x6r=hround(.5w+u+.5fat_curve);
  178. z1=z2+whatever*(z5-z6); filldraw stroke z1e--z2e;  % serif
  179. filldraw stroke z2e{z1-z2}...z3e{right}..{right}z4e
  180.  ...{2(x5-x6),y5-y6}z5e;  % bar
  181. filldraw circ_stroke z6e{up}...{2(x5-x6),y5-y6}z5e;  % diagonal
  182. penlabels(1,2,3,4,5,6); endchar;
  183.  
  184. cmchar "Italic numeral 8";
  185. beginchar("8",9u#,fig_height#,0);
  186. italcorr fig_height#*slant-.5u#;
  187. adjust_fit(0,0);
  188. numeric top_thickness,mid_thickness,bot_thickness,upper_side,lower_side,theta;
  189. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  190. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  191. x0=.5w; y0=.54h;
  192. if hefty: mid_thickness=vround 2/3vair; upper_side=hround(stem-3stem_corr);
  193.  lower_side=hround min(.5[curve,cap_curve]-stem_corr,upper_side+.25u);
  194.  penpos1(top_thickness,90); penpos2(upper_side,180);
  195.  penpos3(mid_thickness,270); penpos8(upper_side,360);
  196.  penpos4(mid_thickness,90); penpos7(lower_side,180);
  197.  penpos6(bot_thickness,270); penpos5(lower_side,360);
  198.  penpos0(vair,90); z3l=z0r; z4l=z0l;
  199.  x1=x6=.5w; x2r=w-x8r=hround u; x7r=w-x5r=hround .75u;
  200.  top y1r=h+o; bot y6r=-o; y2=y8=.5[y1l,y3l]; y7=y5=.5[y4l,y6l];
  201.  filldraw stroke pulled_arc.e(1,2)
  202.   & pulled_arc.e(2,3);  % left half of upper bowl
  203.  filldraw stroke pulled_arc.e(4,5)
  204.   & pulled_arc.e(5,6);  % right half of lower bowl
  205.  filldraw stroke pulled_arc.e(6,7)
  206.   & pulled_arc.e(7,4);  % left half of lower bowl
  207.  filldraw stroke pulled_arc.e(3,8)
  208.   & pulled_arc.e(8,1);  % right half of upper bowl
  209. else: pickup fine.nib; theta=90-angle(18u,h); slope:=-h/18u;
  210.  upper_side=max(fine.breadth,hround(.5[hair,stem]-stem_corr));
  211.  lower_side=hround(.5[hair,stem]+stem_corr);
  212.  pos1(top_thickness,-90); pos6(bot_thickness,-90);
  213.  x1=x6=.5w; top y1l=h+o; bot y6r=-o; pos0(cap_stem,theta);
  214.  lft x2l=w-rt x8l=hround 1.25u; lft x7r=w-rt x5r=hround .75u;
  215.  x2r-x2l=upper_side-fine; x5r-x5l=lower_side-fine;
  216.  ellipse_set(1l,2l,3l,0l); ellipse_set(1r,2r,3r,0r);
  217.  ellipse_set(6l,5l,4l,0l); ellipse_set(6r,5r,4r,0r);
  218.  numeric tau; tau=max(.8,.20710678/(superness-.5));
  219.  filldraw stroke z1e{left}..tension atleast tau..z2e{down}
  220.   ..z3e---z4e..z5e{down}..tension atleast tau..z6e{left};  % S stroke
  221.  pos7(lower_side,180); pos8(upper_side,180);
  222.  y7=.5[y5l,y5r]; y8=.5[y2l,y2r]; pos9(vair,90); z9=z0;
  223.  filldraw stroke z1e{right}..tension atleast tau..z8e{down}
  224.   ..tension atleast tau and atleast 1..{-18u,-.618h}z9e; % upper right stroke
  225.  filldraw stroke z6e{left}..tension atleast tau..z7e{up}
  226.   ..tension atleast tau and atleast 1..{18u,.5h}z9e; fi % lower left stroke
  227. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  228.  
  229. cmchar "Italic numeral 9";
  230. beginchar("9",9u#,fig_height#,0);
  231. italcorr fig_height#*slant-.5u#;
  232. adjust_fit(0,0);
  233. numeric top_thickness,bot_thickness,side_thickness,pull;
  234. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  235. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  236. side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
  237. pull=min(.25,1.5superpull);
  238. pickup fine.nib; pos2(bot_thickness,-90);
  239. pos3(side_thickness,0); pos4(top_thickness,90);
  240. pos5(side_thickness,180); pos6(vair,270);
  241. w-rt x3r=lft x5r=hround max(.75u,1.5u-.5side_thickness);
  242. x4-.1u=x6+.1u=x2+.75u=.5w;
  243. bot y2r=-o; y3=.5[y2,y4]; top y4r=h+o;
  244. y5=.5[y4,y6]; bot y6=vround 3/8h-o;
  245. path p; p=pulled_super_arc.l(3,4)(pull);
  246. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  247. pos7(thin_join,360); z7l=point t of p;
  248. (x,y6r)=whatever[z7l,z6l]; x6r:=max(x,.5[x5r,x6]);
  249. filldraw stroke pulled_super_arc.e(2,3)(pull)
  250.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  251.  & {{less_tense;
  252.  pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
  253.  & z6e{right}...{direction t of p}z7e;  % arc and bowl
  254. if serifs: pos1(hair,-180); pos0(flare,-180);
  255.  lft x0r=min(lft x2-eps,hround 1.2u);
  256.  y0=vround max(.1h+.5flare,.15h-.5flare)-o;
  257.  {{less_tense; bulb(2,1,0)}};  % arc and bulb
  258. else: pos1(.1[bot_thickness,flare],-120);
  259.  bot y1r=vround .07h-o; lft x1r=hround 1.3u;
  260.  filldraw stroke term.e(2,1,left,.9,4); fi  % terminal
  261. penlabels(0,1,2,3,4,5,6,7); endchar;
  262.  
  263.